Access - Ndarja e të dhënave sipas alfabetit

[mastersoft]

pershendetje

Jam duke punuar nje program ne access dhe me nevojitet te bej ndarjen e dhenave sipas shkronjave te apfabetit , duke krijuar ne form disa butona A B C D E etj. dhe kur i shtypim p.sh A te shaqen te gjithe emrat qe fillojne me A.

Tabela :

Emri Mbriemri Tel
john smith 051651
Mike brown 68461531
Jim bellushi 54153


Dhe ne forme te shfaq butonat A B C D E F G H I J K L M N NJ O P......dhe
kur shyp P.sH shkonjen J ne form

Te shfaqen te dhenat

john smith 051651
Jim bellushi 54153

[edspace]

Këtu kam bashkëngjitur një databazë shembull (NdarjeSipasAlfabetit.zip) që filtron emrat sipas alfabetit të shqipes.



Kur shtyp një prej butonave (p.sh. A), formulari filtrohet me një kërkesë të tillë:

SELECT *
FROM tabela
WHERE kolona LIKE 'A*'

Por në alfabetin tonë kemi edhe dyshkronjëshat Dh, Gj, Nj, Ll, Rr, Sh, Th, Xh, Zh të cilat e vështirësojnë pak filtrimin.

Marrim si shembull shkronjat D dhe Dh. Për D-në duhet të eliminojmë emrat që fillojnë me Dh, prandaj e ndryshojmë kërkesën kështu:

SELECT *
FROM emrat
WHERE emri LIKE 'D*'
AND emri NOT LIKE 'Dh*'

Për Dh-në, nuk është nevoja të ndryshojmë kërkesën.

SELECT *
FROM emrat
WHERE emri LIKE 'Dh*'


Ja dhe kodi i plotë VBA që kryen filtrimin për të gjitha shkronjat. Kodi i filtrimit është në vetëm një procedurë e cila thërritet nga të gjitha procedurat e tjera.

Option Compare Database

' Shfaq në formular vetëm emrat që fillojne me 'fillonMe'
Private Sub Filtro_FillonMe(fillonMe As String)
    Filtro_FillonMe_FillonPa fillonMe, ""
End Sub

' Shfaq në formular vetëm emrat që fillojne me 'fillonMe'
' por jo me 'nukFillonMe'. Nese argumentet jane bosh, emrat nuk filtrohen.
Private Sub Filtro_FillonMe_FillonPa(fillonMe As String, nukFillonMe As String)
    
    Dim kerkesa As String
    kerkesa = "SELECT * FROM Emrat"
    
    If Len(fillonMe) > 0 Then
        kerkesa = kerkesa & " WHERE emri LIKE '" & fillonMe & "*'"
        
        If Len(nukFillonMe) > 0 Then
            kerkesa = kerkesa & " AND emri NOT LIKE '" & nukFillonMe & "*'"
        End If
    
    End If
    
    kerkesa = kerkesa & " ORDER BY emri"
    
    Me.RecordSource = kerkesa
    
End Sub

Private Sub TëGjithë_Click()
    Filtro_FillonMe_FillonPa "", ""
End Sub
Private Sub A_Click()
    Filtro_FillonMe "A"
End Sub
Private Sub B_Click()
    Filtro_FillonMe "B"
End Sub
Private Sub C_Click()
    Filtro_FillonMe "C"
End Sub
Private Sub Ç_Click()
    Filtro_FillonMe "Ç"
End Sub
Private Sub D_Click()
    Filtro_FillonMe_FillonPa "D", "Dh"
End Sub
Private Sub Dh_Click()
    Filtro_FillonMe "Dh"
End Sub
Private Sub E_Click()
    Filtro_FillonMe "E"
End Sub
Private Sub Ë_Click()
    Filtro_FillonMe "Ë"
End Sub
Private Sub F_Click()
    Filtro_FillonMe "F"
End Sub
Private Sub G_Click()
    Filtro_FillonMe_FillonPa "G", "Gj"
End Sub
Private Sub Gj_Click()
    Filtro_FillonMe "Gj"
End Sub
Private Sub H_Click()
    Filtro_FillonMe "H"
End Sub
Private Sub I_Click()
    Filtro_FillonMe "I"
End Sub
Private Sub J_Click()
    Filtro_FillonMe "J"
End Sub
Private Sub K_Click()
    Filtro_FillonMe "K"
End Sub
Private Sub L_Click()
    Filtro_FillonMe_FillonPa "L", "Ll"
End Sub
Private Sub Ll_Click()
    Filtro_FillonMe "Ll"
End Sub
Private Sub M_Click()
    Filtro_FillonMe "M"
End Sub
Private Sub N_Click()
    Filtro_FillonMe_FillonPa "N", "Nj"
End Sub
Private Sub Nj_Click()
    Filtro_FillonMe "Nj"
End Sub
Private Sub O_Click()
    Filtro_FillonMe "O"
End Sub
Private Sub P_Click()
    Filtro_FillonMe "P"
End Sub
Private Sub Q_Click()
    Filtro_FillonMe "Q"
End Sub
Private Sub R_Click()
    Filtro_FillonMe_FillonPa "R", "Rr"
End Sub
Private Sub Rr_Click()
    Filtro_FillonMe "Rr"
End Sub
Private Sub S_Click()
    Filtro_FillonMe_FillonPa "S", "Sh"
End Sub
Private Sub Sh_Click()
    Filtro_FillonMe "Sh"
End Sub
Private Sub T_Click()
    Filtro_FillonMe_FillonPa "T", "Th"
End Sub
Private Sub Th_Click()
    Filtro_FillonMe "Th"
End Sub
Private Sub U_Click()
    Filtro_FillonMe "U"
End Sub
Private Sub V_Click()
    Filtro_FillonMe "V"
End Sub
Private Sub X_Click()
    Filtro_FillonMe_FillonPa "X", "Xh"
End Sub
Private Sub Xh_Click()
    Filtro_FillonMe "Xh"
End Sub
Private Sub Y_Click()
    Filtro_FillonMe "Y"
End Sub
Private Sub Z_Click()
    Filtro_FillonMe_FillonPa "Z", "Zh"
End Sub
Private Sub Zh_Click()
    Filtro_FillonMe "Zh"
End Sub

' Autori: Eduard Papa

Nëse do ta përdorësh kodin më lart në shumë formularë, mund ta ndryshosh që të marrë emrin e tabelës dhe kolonës (emrit) si argument dhe ta vendosësh në një modulë (module).

[mastersoft]

A mund te me shpjegosh pak me hollesit se si ta perdor kete kod sepse sjam shume i mire ne Access ? ku ta ve ?

[edspace]

E hape databazën shembull që bashkangjita më lart? Në databazë ke tabelën që ruan informacionin dhe formularin që kryen filtrimin me butonat. Hap formularin dhe shikoje se si është krijuar. Për të parë kodin, kliko ikonën e kodit në shiritin në krye, në cepin djathtas.

Në figurën më poshtë kam ilustruar hapat që duhet të ndjekësh për të shtuar funksionin e butonave.

[mastersoft]

Kjo metode spo funksion jo vetem siq e bej une por edhe ne formularin e bashkangjtur

[edspace]

Databaza punon për mrekulli në kompjuterin tim. Unë e kam krijuar në Microsoft Access 2007 por e ruajta në formatin e Access 2000, kështu që duhet të punojë edhe me versionet e tjera.

I vetmi problem mund të jetë nëse ti nuk lejon ekzekutimin e makrove (macros). Kur hap databazën, Access zakonisht të njofton që kjo databazë përmban makro dhe të pyet nëse do t'i lejosh apo jo. Aty zgjidh "enable" për t'i aftësuar makrot. Shiko ndihmën e Access se si mund t'i aftësosh makrot në versionin e Access që përdor ti.

[mastersoft]

a mund te postosh nje tjeter per access 2007 sepse une e ka nje te tille