VB: Si te shtoj presjet dhe pikat ne nje numer?

[My_Soul]

Kam nje detyre te tille.

Jepet numri p.sh 78945632 dhe une te ndertoj nje algoritem dhe codet per ve presjet dhe piken dhjetore: 789,456.32

A i ka kush gati algoritmin dhe codet ne Visual Basic?

Thank you in advance

[edspace]

Nuk ke qene shume i qarte me ate qe ke kerkuar

Nqs fillojme ti numerojme shifrat nga ana e djathte atehere 78945632 = 78,945,632

Nqs fillojme ti numerojme shifrat nga ana e majte atehere 78945632 = 789,456.32

Por sikur ti te japesh numrin 789456321
Cfare duhet te beje programi?
789,456,321
7.89456321
78.9456321
789.456321
7,894.56321
78,945.6321
789,456.321
7,894,563.21
78,945,632.1


Pra duhet te vendosesh se ku mbaron numri i plote dhe ku fillon mbetja dhjetore. Lexoje me kujdes detyren qe te ka dhene mesuesi dhe na jep pergjigjen.


Me poshte ke nje funksion nga planet-source-code.com

Ky funksion perdor sistemin amerikan te numrave, ate qe ke kerkuar dhe ti. Nqs do te perdoresh sistemin Shqiptar, atehere ne kodin me poshte duhet te ndryshosh "," me "." dhe anasjelltas.

Per funksionin me poshte
Numri 78945632 do kthehet ne 78,945,632
Numri 789456.32 do kthehet ne 789,456.32
Numri 7894.5632 do kthehet ne 7,894.5632

Kodin me poshte mund ta perdoresh keshtu:

dim numri as double
dim num_me_presje as string

numri = 78945632
num_me_presje = AddCommas( numri )

msgbox "numri " & numri & " u kthye ne " & num_me_presje

Kodi me lart do nxjerre ne ekran mesazhin
numri 78945632 u kthye ne 78,945,632

'**************************************
' Name: Add Commas
' Description: This Function adds commas 
'     to number strings
' By: SG_
'
' Inputs: A Double value
'
' Returns: A String with commas inserted
'
'This code is copyrighted and has' limited warranties.Please see http://w
'     ww.Planet-Source-Code.com/vb/scripts/Sho
'     wCode.asp?txtCodeId=3518&lngWId=1'for details.
'**************************************


Public Function AddCommas(ByVal Number As Double)
    Dim NewNumber As String
    Dim DecimalPart As String
    Dim Temp As String
    Dim TestNumber As String
    
    TestNumber = CStr(Number)
    

    For x = 1 To Len(TestNumber)
        Temp = Left(TestNumber, x)


        If Right(Temp, 1) = "." Then
            DecimalPart = Right(TestNumber, Len(TestNumber) - x)
            TestNumber = Left(TestNumber, (x - 1))
        End If
    Next x
    


    If (Len(TestNumber) Mod 3) <> 0 Then
        NewNumber = Left(TestNumber, (Len(TestNumber) Mod 3))
        NewNumber = NewNumber & ","
        TestNumber = Right(TestNumber, Len(TestNumber) - (Len(TestNumber) Mod 3))
    End If
    


    Do While (Len(TestNumber) > 3)
        NewNumber = NewNumber & Left(TestNumber, 3)
        NewNumber = NewNumber & ","
        TestNumber = Right(TestNumber, Len(TestNumber) - 3)
    Loop
    
    NewNumber = NewNumber & TestNumber
    


    If DecimalPart <> "" Then
        NewNumber = NewNumber & "."
        NewNumber = NewNumber & DecimalPart
    End If
    
    AddCommas = NewNumber
    
End Function

[My_Soul]

Ed, shume thanks, por nuk eshte algoritmi i duhur.

Mbase edhe une nuk jam shpjeguar mire.
Po ta shpjegoj me shembuj:

Jepet numri: 458796
Rezultati duhet te jete: 4,587.96

Jepet numri: 8956
Rezultati duhet te jete: 89.56

Pra, pasi te jepet numri programi ta ktheje ate ne sistemin american.

[edspace]

Dmth dy numrat e fundit (djathtas) jane shifrat dhjetore.
Me poshte ke funksionin e ri.

Ja disa shembuj duke perdorur kete program.

0 = 0.0
12 = 0.12
123 = 1.23
1234 = 12.34
12345 = 123.45
123456 = 1,234.56
1234567 = 12,345.67
12345678 = 123,456.78
123456789 = 1,234,567.89

Public Function AddCommas(ByVal Number As Long)
    
    Dim strNumber As String
    Dim IntegerPart As String
    Dim DecimalPart As String
    Dim NewIntegerPart As String
    Dim DecimalDigits As Integer
    
    DecimalDigits = 2

    strNumber = CStr(Number)
    
    If Len(strNumber) <= DecimalDigits Then
        AddCommas = "0." & strNumber
        Exit Function
    End If
    
    DecimalPart = Right(strNumber, DecimalDigits)

    IntegerPart = Left(strNumber, Len(strNumber) - DecimalDigits)
    
    Do While (Len(IntegerPart) > 3)
        NewIntegerPart = "," & Right(IntegerPart, 3) & NewIntegerPart
        IntegerPart = Left(IntegerPart, Len(IntegerPart) - 3)
    Loop
    
    NewIntegerPart = IntegerPart & NewIntegerPart
    
    AddCommas = NewIntegerPart & "." & DecimalPart
    
End Function

Kodi me lart i komentuar, qe ta kuptosh se cfare ben cdo rresht:

Public Function AddCommas(ByVal Number As Long)

    ' variabla qe e kthen numrin nga long ne string
    Dim strNumber As String
   
    ' pjesa e numrit te plote ne string
    Dim IntegerPart As String 
    
    ' pjesa dhjetore ne string
    Dim DecimalPart As String     
    
    ' numri i plote me presje
    Dim NewIntegerPart As String 
    
    ' numri dhjetor me presje
    Dim DecimalDigits As Integer
    
    ' numri i shifrave dhjetore =2,3,4, ....sa te duash
    ' ne kete rast e kemi 2
    DecimalDigits = 2

    ' kthejme numrin ne string (tekst)
    strNumber = CStr(Number)
    
    ' nqs numri i shifrave eshte i barabarte ose me i vogel sesa
    ' numri i shifrave dhjetore, atehere ktheje ne 0.xxxxx
    ' dhe dil nga funksioni
    If Len(strNumber) <= DecimalDigits Then
        AddCommas = "0." & strNumber
        Exit Function
    End If
    
    ' ketu marrim pjesen dhjetore te numrit nga ana e djathte
    DecimalPart = Right(strNumber, DecimalDigits)
    
    ' ketu marrim pjesen e numrit te plote nga ana e majte
    IntegerPart = Left(strNumber, Len(strNumber) - DecimalDigits)
    
    ' Per aq kohe sa numri i plote eshte me i madh se tre
    ' Merr 3 shifrat e fundit nga integerpart dhe ndaji me presje tek newintegerpart
    ' pastaj vazhdo me tre shifrat e tjera
    ' psh
    ' ---------------------------------
    ' newintegerpart = bosh
    ' integerpart = 12345678
    ' ----------------------------------
    ' newintegerpart = ,678
    ' integerpart = 12345
    ' ---------------------------------- 
    ' newintegerpart = ,345,678
    ' integerpart = 12
    ' -----------------------------------
    Do While (Len(IntegerPart) > 3)
        NewIntegerPart = "," & Right(IntegerPart, 3) & NewIntegerPart
        IntegerPart = Left(IntegerPart, Len(IntegerPart) - 3)
    Loop
    
    ' bashko shifrat pa presje me shifrat me presje
    ' psh   "12" & ",345,678" = "12,345,678"
    NewIntegerPart = IntegerPart & NewIntegerPart
    
    ' bashko pjesen e plote me pjesen dhjetore duke i ndare me "."
    AddCommas = NewIntegerPart & "." & DecimalPart
    
End Function

[My_Soul]

Thank you Ed!