si ta bej me "LICENSE" nje databaze n Access 2007

[nince_tutes]

Pershendetje!
Kam krijuar nje DB n access 2007, dhe ja kam instaluar klientit, por dua q ta bej t limituar kohen e perdorimit t saj, pra mbas nje viti, "T KERKOJ RI-AKTIVIZIM", a dicka tjeter t ngjashme, n menyre q vetem un t'ja jap kete t drejte.

Gjithashtu, dua q ajo databaze t exekutohet vetem n ate komopjuter ku un e kam instaluar, pra t mos ta marre me copy/paste dhe ta perdor diku tjeter.

Cfare m keshilloni q t bej? si t'ja bej?
flm per sugjerimet tuaja.
Respekte.

[hot_prinz]

Ne nje modul te databazes krijon funksione qe kur hapet databaza.

1.) Per limitim te kohes:
- nje funksion qe kontrollon daten e sistemit dhe e krahason me nje date deri kur te funksionoje databaza, kjo date mund te fshihet ne nje file ne windows folder, e mund te vazhdohet sipas nevojes,

2.) Per limit vetem ne nje kompjuter:
- nje funksion qe lexon numrin serial te harddiskut dhe e krahason me numrin e hardiskut ku eshte instaluar databaza, edhe ky numer i hardiskut mund te fshihet ne file te njejte si data me pare.

[nince_tutes]

Po si eshte ky modul n Access 2007 q lexon serialin e hdd?? un kam gjetur nje, por eshte n visual basic.

Po nqs useri ndryshon daten e kompjuterit, ai vazhdon perseri t punoje me programin, apo jo.

[hot_prinz]

Po si eshte ky modul n Access 2007 q lexon serialin e hdd?? un kam gjetur nje, por eshte n visual basic.

Nje menyre per te marre numrin serial te hd ne VBA:

Option Compare Database

Private Sub Form_Load()

    MsgBox (MerrSerialin())

End Sub


Function MerrSerialin() As String

    Dim obj As Object
    Dim WMI As Object
    
    Set WMI = GetObject("WinMgmts:")
    
    For Each obj In WMI.InstancesOf("Win32_PhysicalMedia")
        MerrSerialin = obj.SerialNumber
        Exit For
    Next

End Function

Po nqs useri ndryshon daten e kompjuterit, ai vazhdon perseri t punoje me programin, apo jo.

Ne file te fshehur ne sistem krijon nje parameter per daten e aktuale, sa here startohet databaza kontrollon daten e dites se sotme dhe e aktualizon ne parameter, nese gjate kontrollimit dikton qe data e sistemit eshte me e vjeter se data e aktualizuar ne parameter e di se useri e ka nderrruar daten dhe ndalon qe te fuksionoje databaza, perderisa data e kontrolluar te jete me e re se data ne parameter.

[nince_tutes]

Hot_Priz.
E provova kodin q m the, e futa n nje forme tek eventi on_load, dhe m pas kopjova edhe pjesen e meposhtme.

Por kur e hap formen, m jep gabim. Po vendos edhe fotot q m dalin.

Nese mundesh, beji upload nje db t thjeshte vetem me nje forme, ku exekutohet ky kod.

Shume faleminderit.

[hot_prinz]

Ja nje databaze e thjeshte ne Access 2007, tek une po punon.

[nince_tutes]

Hot_Priz!

E shkarkova db tende, por m jep t njetat mesazhe si n rastin tim, dhe nuk po i vendos n attach, pasi jane identike.

Ku mund t jete problemi? un jam me XP-SP2.

Po per punen e KOHES/TIMERIT? m jep dicka m shume si keshille, a qofte dhe nje shembull i thjeshte.

Ndihma jote eshte sh e cmuar, dhe t falenderoj per pergjigjet e shpejta.

[hot_prinz]

Fute kete kod ne Forme dhe ekzekutoje:

    

Option Compare Database

Private Sub Form_Load()

    Dim obj As Object
    Dim WMI As Object
    
    Set WMI = GetObject("WinMgmts:")
    
    For Each obj In WMI.InstancesOf("Win32_PhysicalMedia")
        MsgBox (obj.SerialNumber)
    Next

End Sub

Me For Each Loop i merr numrat e seciles "device" ne pc, ndrro kodin ne db ne kete forme dhe trego se a po te lexohet ndonje numer serial dhe a mos ke floppy A ne PC? Une me Exit For e ndalja Loopin per te marre numrin serial te hd primar.

Per timer me duhet pak kohe po e pershtati ne VBA nje db te thjeshte si po mendoj.

[nince_tutes]

e futa kete kod n nje forme tjeter boshe fare.

M del perseri error, keraj radhe tek:
MsgBox (obj.SerialNumber)

N pritje jam.
Shume faleminderit

[hot_prinz]

Ky eshte kodi qe funksionon me vertetimin e numrit serial te hd dhe me verifikimin per limitin e kohes, plus vertetimit nese perdoruesi kthen kohen e sistemit prapa:

Option Compare Database

Dim FileArray() As String

Private Sub Form_Load()

    Dim file As String
        
    file = "C:\Windows\Test.txt"
    LexoNgaFile (file)

    If NS_Kontrolla() = True Then

        If Kontrollo_Daten = True Then
            AktualizoParametrin ("DR")
            ShkruajNeFile (file)
        Else
            MsgBox ("Probleme me daten ne Kopjuter!")
            DoCmd.CloseDatabase
        End If
    
    Else
    
        MsgBox ("Ne kete Kompjuter nuk keni Licence per te perdorur Databazen!")
        DoCmd.CloseDatabase
        
    End If

End Sub

Function Kontrollo_Daten() As Boolean

    Dim koha_aktuale As Date
    data_aktuale = Now()
    
    Dim koha_ruajtur As Date
    data_ruajtur = CDate(MerrParametrin("DR"))
    
    Dim koha_valide As Date
    data_valide = CDate(MerrParametrin("DV"))
    
    If CLng(data_aktuale) < CLng(data_valide) Then
        If CLng(data_aktuale) < CLng(data_ruajtur) Then
            Kontrollo_Daten = False
        Else
            Kontrollo_Daten = True
        End If
    Else
        Kontrollo_Daten = False
    End If
    

End Function

Function NS_Kontrolla() As Boolean

    Dim NrSerial As String
    Dim NrSerialInstalluar As String
    
    NrSerial = MerrSerialin()
    NrSerialInstalluar = MerrParametrin("NS")
    
    NS_Kontrolla = Trim(LCase(NrSerial)) Like Trim(LCase(NrSerialInstalluar))

End Function

Sub AktualizoParametrin(emri As String)

    Dim i As Integer
    
    For i = 0 To UBound(FileArray)
        If InStr(1, FileArray(i), emri) > 0 Then
            FileArray(i) = "DR=" & Now()
        End If
    Next

End Sub

Function MerrParametrin(emri As String)

    Dim s
    Dim STemp() As String

    For Each s In FileArray
        If InStr(1, s, emri) > 0 Then
            STemp = Split(s, "=")
        End If
    Next
    
    MerrParametrin = STemp(1)
    
End Function

Function MerrSerialin() As String

    Dim obj As Object
    Dim WMI As Object
    
    Set WMI = GetObject("WinMgmts:")
    
    For Each obj In WMI.InstancesOf("Win32_PhysicalMedia")
        MerrSerialin = obj.SerialNumber
        Exit For
    Next

End Function

Sub ShkruajNeFile(file As String)

    Dim s
    Dim f As Integer
    
    f = FreeFile
    
    Open file For Output As #f
    
    For Each s In FileArray
        Print #f, s
    Next
    
    Close f

End Sub

Sub LexoNgaFile(file As String)

    Dim f As Integer
    f = FreeFile
    
    Open file For Input As #f
        FileArray = Split(Input(LOF(f), #f), vbCrLf)
    Close f

End Sub

Permbajtja e File "C:\Windows\Test.txt":

NS=V92SPSL0
DV=01.05.2011 23:59:59
DR=29.04.2011 20:32:34

NS = Numri Serial I Hardiskut
DV = Maksimumi i Dates Valide
DR = Data e Ruajtur (per kontrolle nese useri e kthen kohen e sistemit prapa)


****

Nese ty nuk te funksionon leximi i numrit serial te hardiskut, beji nje vertetim nese File "C:\Windows\Test.txt" gjindet ne sistem, se nuk po e di pse nuk po te funksionon ty.