Si të mbroj databazën në Access 2007 nga kopjimi?

[Islam_Beka]

Ja implementimi i nje shembulli te thjesht si mund te kontrollohet numri i hardiskut te nje kompjuteri dhe vlersimi se a mund te perdorim apo jo kete program ne kete hardisk, nese numri nuk perputhet accessi do te perfundoje (Kujdes ketu se mund te bllokosh edhe programin tend). Para se te perdorni kete cope kodi ruani programet tuaja ne nje vend tjeter!

Option Compare Database

    Private Sub Form_Load()
        Dim serHardisk As Long
        serHardisk = GetDriveSerialNumber
        If serHardisk = 815 Then
            MsgBox "Numri serial hardiskut " & Left(AppPath, 1) & ":\ eshte " & GetDriveSerialNumber & _
            vbCrLf & "Ju keni te drejte te perdorni kete Program!", vbOKOnly + vbInformation
            
        Else
            MsgBox "Numri serial hardiskut " & Left(AppPath, 1) & ":\ eshte " & GetDriveSerialNumber & _
            vbCrLf & "Ju nuk keni te drejte te perdorni kete Program!" & vbCrLf & "PAPA!", vbOKOnly + vbInformation

            Dim a
            a = InputBox("Jepni numrin e sakte serial!")
            If serHardisk = a Then
                MsgBox "Numri serial hardiskut " & Left(AppPath, 1) & ":\ eshte " & GetDriveSerialNumber & _
                vbCrLf & "Ju keni te drejte te perdorni kete Program!", vbOKOnly + vbInformation
            Else
                MsgBox "Numri serial hardiskut " & Left(AppPath, 1) & ":\ eshte " & GetDriveSerialNumber & _
                vbCrLf & "Ju nuk keni te drejte te perdorni kete Program!" & vbCrLf & "PAPA!", vbOKOnly + vbInformation
                'DoCmd.Quit 'Mbyll Accessin dhe Databazen! PERDORE ME KUJDES SEPSE MUND TA BLLOKOSH PROGRAMIN TEND
            End If
        End If
        
    End Sub
      
    Public Function GetDriveSerialNumber(Optional ByVal DriveLetter As String) As Long
        Dim fso As Object, Drv As Object
        Set fso = CreateObject("Scripting.FileSystemObject")
        If DriveLetter <> "" Then
            Set Drv = fso.GetDrive(DriveLetter)
        Else
            Set Drv = fso.GetDrive(fso.GetDriveName(AppPath))
        End If
        With Drv
            If .IsReady Then
                DriveSerial = Abs(.SerialNumber)
            Else
                DriveSerial = -1
            End If
        End With
        Set Drv = Nothing
        Set fso = Nothing
        GetDriveSerialNumber = DriveSerial
    End Function

    Public Function AppPath() As String
        Dim sPath As String
        sPath = CurrentDb.Name
        While Right$(sPath, 1) <> "\"
            sPath = Left$(sPath, Len(sPath) - 1)
        Wend
        AppPath = sPath
    End Function

per te kontrolluar se sa here eshte hapur ky program nga perdoruesi mund te perdoret nje tekstfile e fshehur diku ne system qe numron startimet e programit dhe nese startimet e paregjistruara arrijne numrin 3 atehre mund te aktivizohet nje funksion qe fshin databazen prej sistemi.

po si ke ban qat fajll si e lexon se sa her esht startuar programi me qfar programi me ban

[hot_prinz]

po ate fajll e krijon ti vete,

per te krijuar ate fajll qe permban numrin e startimeve derisa programi eshte i paregjistruar duhet te percaktosh nje vend ne sistem per te cilin ti mendon se eshte i sigurte dhe nuk mund te diktohet lehte, disa programe psh. vendosin fajlla ne skeden e windowsit, pas krijimit mund te ndrrosh atributet e fajllit ne fshehtesi/hidden, emrin e fajllit mund te permbaje me shume bashketingellore se zanore si psh. "zhmnjwz.ax".

Ja nje shembull i thjeshte si me e gjete skeden e windowsit edhe nese eshte instaluar jo si standart ne "C:\windows\" por ne "X:\blablabla\" pastaj verifikon nese fajlli i fshehur gjindet aty, nese nuk gjindet atehere programi starton per here te pare i paregjistruar krijon nje fajll te ri dhe vendos nje 1, ne te kunderten nese fajlli gjindet ne sistem atehere e hap ate e merr numrin qe gjindet aty dhe perderisa nuk eshte arritur maksimumi i startimeve te caktuara i shton nje 1, kurse nese maksimumi ka arrite atehere perfundon programin, per ta mashtruar programin qr te startoje perseri vetem vendos nje 1 ne fajllin "zhmnjwz.ax".

Option Compare Database

Private Declare Function GetWindowsDirectory Lib "kernel32" _
    Alias "GetWindowsDirectoryA" (ByVal lpBuffer As String, _
    ByVal nSize As Long) As Long

Function GetWinDir() As String
  Dim strDir As String
  Dim nLen   As Long
  
  strDir = Space(255)
  nLen = GetWindowsDirectory(strDir, 255)
  strDir = Left(strDir, nLen)
  
  If Right$(strDir, 1) <> "\" Then strDir = strDir & "\"

  GetWinDir = strDir
End Function

Private Sub Form_Load()

    Dim fajlliIm As String, tmpStr As String, f, tmpInt
    fajlliIm = GetWinDir & "zhmnjwz.ax"
    tmpStr = Dir(fajlliIm)
    f = FreeFile
    
    If tmpStr <> "" Then
        Open fajlliIm For Input As #f
        Do While Not EOF(f)
        Line Input #f, tmpInt
        Loop
        Close #f
        
        If Trim(tmpInt) <= 3 Then
            
            MsgBox "Startimi i programit nr: " & tmpInt, vbInformation + vbOKOnly, "Startimet e paregjistruara!"
            
            tmpInt = tmpInt + 1
            Open fajlliIm For Output As #f
            Print #f, tmpInt
            Close #f

        Else
            MsgBox "Koha e perdorimit pa u regjistruar ka perfunduar!" _
             , vbInformation + vbOKOnly, "Papa!"
             DoCmd.Quit
        End If
    Else
        Open fajlliIm For Output As #f
        Print #f, "1"
        Close #f
    End If

End Sub

[furkan]

Pershendetje:
Ajo qe ti se pari duhet te besh eshte se ajo database duhet te kete nje form e cila do te ekzekutohet ne momentin kur te hapet baza e te dhenave
kete e bene me macro ose ne startup e deklaron formen per hapje apo llogimi
e krijone nje fajll tekstual apo qfare do fajlli ne ndonje shteg te fshehur thelle psh C:\Windows\System32\Licenca.txt dhe forma duhet ta kerkoj kete fajll me emrin licenca.txt
dhe ne modin Properties ne rubriken One Execute e vendos Kodin burimor.

Private Sub Command0_Click()
If Len(Dir("C:\WINDOWS\System32\Licenca.txt")) > 0 Then
MsgBox ("Baza Shfrytezohet legalisht")
DoCmd.OpenForm "Form1", stnormal
Else
MsgBox ("baza eshte kopjuar ilegalisht programi mbyllet")
DoCmd.Close
End If
End Sub
per ndonje informate me te hollesishme me informo
ju presim per bashkpunim

[valdetshala]

Pershendetje:
Ajo qe ti se pari duhet te besh eshte se ajo database duhet te kete nje form e cila do te ekzekutohet ne momentin kur te hapet baza e te dhenave
kete e bene me macro ose ne startup e deklaron formen per hapje apo llogimi
e krijone nje fajll tekstual apo qfare do fajlli ne ndonje shteg te fshehur thelle psh C:\Windows\System32\Licenca.txt dhe forma duhet ta kerkoj kete fajll me emrin licenca.txt
dhe ne modin Properties ne rubriken One Execute e vendos Kodin burimor.

Private Sub Command0_Click()
If Len(Dir("C:\WINDOWS\System32\Licenca.txt")) > 0 Then
MsgBox ("Baza Shfrytezohet legalisht")
DoCmd.OpenForm "Form1", stnormal
Else
MsgBox ("baza eshte kopjuar ilegalisht programi mbyllet")
DoCmd.Close
End If
End Sub
per ndonje informate me te hollesishme me informo
ju presim per bashkpunim

furkan te lumte se kete e kam provuar dhe funkcionon poshtu edhe ne Private Sub Form_Load() vetem se te DoCmd.Close e kam ndryshuar ne DoCmd.Quit dhe ok,,edhe me serial te hard diskut ish e sigurt por nuk po di qka pas formatizimit rasishte, mos po ndryshon diqka.