Access: Menu në vend të butonave!

[little-boy]

Tung te gjithve: po ja bashkangjes nje "PrintScreen" nje baze te te dhenave, ajo qe mua me intereson se si ka mundur autori i ksaj baze ti vendos funksionet e veta ne "MENU" . Une keto funksione i kam ne buttona mirpo me duket me profesionel sikur te mundesha ti vendosi ne Menu.

Ndihma eshte lart e Vlersuar

[hot_prinz]

pershendetje,

ja nje shembull per krijimin e nje menyje ne Access 2003.

kodi per Formen:

Option Compare Database

Const emriMenyse = "Menyja Ime"

Private Sub Form_Load()

    Call krijo_meny_te_re
    
End Sub

Private Sub krijo_meny_te_re()
    
    Call ristarto_menyne
    
    Application.CommandBars("Menu Bar").Enabled = False
    
    Set menyBar = CommandBars.Add(Name:=emriMenyse, MenuBar:=True)
    
    Set meny1 = menyBar.Controls.Add(Type:=msoControlPopup)
    Set meny2 = menyBar.Controls.Add(Type:=msoControlPopup)
    Set meny3 = menyBar.Controls.Add(Type:=msoControlPopup)
    Set meny4 = menyBar.Controls.Add(Type:=msoControlPopup)

    meny1.Caption = "Meny "
    meny2.Caption = "Edito"
    meny3.Caption = "Ruaj"
    meny4.Caption = "Perfundo"
    
    Set cmdButton = meny1.Controls.Add
    With cmdButton
      .Caption = "Fillo"
      .OnAction = "fillo"       'ketu futet emri i funksionit kur menyja klikohet
      .Style = msoButtonCaption
    End With

    Set cmdButton = meny2.Controls.Add
    With cmdButton
      .Caption = "Kopjo"
      .OnAction = "kopjo"
      .Style = msoButtonCaption
    End With

    Set cmdButton = meny3.Controls.Add
    With cmdButton
      .Caption = "Ruaj ne ..."
      .OnAction = "ruaj"
      .Style = msoButtonCaption
    End With

    Set cmdButton = meny4.Controls.Add
    With cmdButton
      .Caption = "Fund"
      .OnAction = "fund"
      .Style = msoButtonCaption
    End With

    CommandBars(emriMenyse).Visible = True
    
End Sub

Sub ristarto_menyne()

    On Error Resume Next
    
    Application.CommandBars(emriMenyse).Delete
    Application.CommandBars("Menu Bar").Enabled = True
    
End Sub 

kodi per Modul:

Option Compare Database

Public Function fillo()
    MsgBox "Klikove ne ""Fillo""", vbOKOnly + vbInformation, "Informacion!"
End Function

Public Function kopjo()
    MsgBox "Klikove ne ""Kopjo""", vbOKOnly + vbInformation, "Informacion!"
End Function

Public Function ruaj()
    MsgBox "Klikove ne ""Ruaj ne ...""", vbOKOnly + vbInformation, "Informacion!"
End Function

Public Function fund()
    MsgBox "Klikove ne ""Fund""", vbOKOnly + vbInformation, "Informacion!"
End Function 

[hot_prinz]

me vjen keq, por kam harruar se te funksionoj kodi me larte duhet te vendoset nje reference me "Microsoft Office Object Library 12.0".

[little-boy]

Flm Per Kodin Hot_prinz, si duhet te vedoset kjo referenc ne access?

[hot_prinz]

per te vendosur nje reference duhet te gjindesh ne VBA-Editor (aty ku mund te ndryshohet kodi i formularit), aktivizohet me Alt + F11 (mban susten Alt te shtypur dhe ne te njejten kohe shtyp F11). Pastaj ne meny te VBA-Editorit:

-> Tools -> References... pastaj hapet nje dialog me emrin References, aty ne liste kerkon per objektin "Microsoft Office 12.0 Object Library", e aktivizon ne kutine para emrit dhe shtyp OK.

Tani eshte vendosur nje reference me objektin "Microsoft Office 12.0 Object Library" qe permban funksionet e nevojitura.

[little-boy]

Hot_prinz, te Faliminderoj pa mas

[nince_tutes]

Hot_prinz, ti je super, sebashku me edspace, por puna eshte se si t behet ne access 2007.