Acess - Kerkim I Bazuar ne Radio Box

[little-boy]

Pershendetje te gjithve,

kam nje Baze te te Dhenave ne Access ne at Baze eshte nje nje tabel tblEmployee ku ka Fushat Emri, Mbiemri, ID,...

nga kjo tabel kam ndertuar nje Query qryEmployee pra tani dua te beje nje form per kerkim te Puntoreve si ne foton me posht...

Ndonje Ndihme ne kete eshte lart e Vlersuar!

[Ardi_Pg_ID]

teorikisht!

nese txtbox e kemi txtKerkim
radio jane punonjesEmri, punonjesMbiemri, punonjesID edhe vete seleksjoni i radio eshte kriteriFusha

if kriteriFusha = emer { fushaEkerkimit = punonjesEmri }
else if kriteriFusha = mbiemer { fushaEkerimit = punonjesMiemri }
else if kriteriFusha = ID { fushaEkerimit = punon jesID }

kerko tabelen eblEmployee ku fusha = fushaEkerkimit dhe kriteri = txtbox txtKerim

kjo esshte pak a shume teworikisht me kod nuk e di ver kodin ta shofe nje nga cunat qe ja pret shume per access


Ardi

[hot_prinz]

ja edhe kodi ne Access pas teorise se Ardit,

Option Compare Database

Private Sub cmdKerkoj_Click()
    
    lstRezultati.RowSource = vbEmbtyString
    txtKerkim.SetFocus
    
    If txtKerkim.Text <> "" Then
        Select Case optGrupi
        Case 1
            kerko Emri.Name, txtKerkim.Text
        Case 2
            kerko Mbiemri.Name, txtKerkim.Text
        Case 3
            kerko ID.Name, txtKerkim.Text
        Case Else
            MsgBox "aktivizo nje kolone per te kerkuar!"
        End Select
    Else
        MsgBox "shkruaj se pari cfare do kerkosh!"
    End If
    
End Sub

Private Sub kerko(textKolona As String, textKerkim As String)

    Dim databaza As DAO.Database
    Dim rekordseti As DAO.Recordset
    Dim komandaSQL As String

    Set databaza = CurrentDb
    komandaSQL = "SELECT * FROM tblEmploye WHERE (" & textKolona & " LIKE '*" & textKerkim & "*')"
    Set rekordseti = databaza.OpenRecordset(komandaSQL)
     
    Do While Not rekordseti.EOF
        lstRezultati.AddItem rekordseti.Fields("Emri") & _
            " ---> " & rekordseti.Fields("Mbiemri") & " ---> " & rekordseti.Fields("ID")
        rekordseti.MoveNext
    Loop
     
    rekordseti.Close
    Set rekordseti = Nothing
    Set databaza = Nothing
    
End Sub 

Baza

[little-boy]

@Hot_Prinz, Artdi, Faliminderit shum per Perpjekjet por une prap nuk arrita ne 100% per shkak se me del mesazhi "Aktivizo nje Kolon per te Kerkuar"

po e bashkangjes bazen per te shiquar se ku po gaboj une,

do te ishte mire qe rezulati i kerkimit te me shafaqet ne Query e jo ne List Box por sidoqoft edhe ne list Box me kryen pune

edhe nje here Faliminderit shumë

[hot_prinz]

LittleBoy,

mesazhi "Aktivizo nje Kolon per te Kerkuar" te ka dalur sepse emri i grupit te opcioneve te ti ishte <textKolona> ne vend te <optGrupit>, poashtu edhe nje vlere e te dhenave ne liste duhet ndryshuar gjerm. <Herkunftstyp>.

Sa i perket shfaqjes se rezultateve te kerkimit ne query, pse duhet te shfaqesh rezultate ne query te Access-it kur vete kerkimi ne kod eshte nje query [SELECT.. FROM.. LIKE..]?

Ketu duhet te dallosh se forma e query-t te Access-it eshte krijuar edhe per (joprogramere apo queryfetishiste..) qe te krijojne nje query, e nese nje programer krijon nje query dinamik me kod atehre nuk ka nevoje per shfaqje rezultatesh ne nje query te access-it, nese me te vertete kjo eshte e nevojshme per cfardo gjeje atehere vie ne pyetje i tere sistemi i Access-it se a eshte i pershtatshem per te krijuar ate projekt.

Une personalisht nuk njof asnje projekt i cili mund te funksionoje me Access-in pa arritur heret a vone ne kufinjte e tij, prandaj nuk filloj kurre nje projekt ne Access!

[little-boy]

Hot_Prinz,

Te Lumtë per zgjidhjen!

Pajtohem se nuk ja vlen te nisesh nje project te madh me MS Access mirpo per Data Baza te vogla qe nuk kan shum transakcione funksionon mire !

E Vlersoj shum Hot_prinz kete Ndihmes.

[hot_prinz]

hey LittleBoy,

kam ndryshuar kete program, kur kerkon tabelen <tblEmployee>, rezultatet e kerkimit do te ruhen ne nje tabele te perkohshme (temporere) me emrin <tblTemp>, kur shtyp pullen per kerkim programi kerkon nese tabela tblTemp ekziston dhe e fshin ate, pastaj krijon tabelen tblTemp te zbrazet dhe ruan rezultatet e kerkimit ne te.

Tani nje report i krijuar me emrin <berEmployee> i cili i merr informacionet nga tabela tblTemp, gjithnje do te permbaje rezultatet e kerkuara dhe do te hapet automatikisht. Ne kete menyre mund te krijohet edhe nje query ne Access i cili permban te dhenat e tblTemp, nese te hyn ne pune per ndonji gje tjeter.

**Kujdes: Mos harro te mbyllesh tabelen <tblTemp> (vetem nese e hap tblTemp per te shiquar cfare ka ne te) para se te kerkosh, sepse programi nuk do te mundet ta fshije tabelen <tblTemp> derisa eshte e hapur dhe do lajmroje nje gabim!

Option Compare Database

Private Sub cmdKerkoj_Click()
    
    lstRezultati.RowSource = vbEmbtyString
    txtKerkim.SetFocus
    
    If txtKerkim.Text <> "" Then
        Select Case optGrupi
        Case 1
            kerko Emri.Name, txtKerkim.Text
        Case 2
            kerko Mbiemri.Name, txtKerkim.Text
        Case 3
            kerko ID.Name, txtKerkim.Text
        Case Else
            MsgBox "aktivizo nje kolone per te kerkuar!"
        End Select
    Else
        MsgBox "shkruaj se pari cfare do kerkosh!"
    End If
    
End Sub

Private Sub kerko(textKolona As String, textKerkim As String)

    Dim databaza As DAO.Database
    Dim rekordseti As DAO.Recordset
    Dim komandaSQL As String
    
    Dim tabela As TableDef
    Dim rekordsetiX As Recordset
    Dim tblName As String
    
    Set databaza = CurrentDb
    tblName = "tblTemp"
    
    mbyll_raportet
    
    fshij_tabelen databaza, tblName
    krijo_tabelen databaza, tblName
    
    komandaSQL = "SELECT * FROM tblEmploye WHERE (" & textKolona & " LIKE '*" & textKerkim & "*')"
    Set rekordseti = databaza.OpenRecordset(komandaSQL)
    
    Set rekordsetiX = databaza.OpenRecordset(tblName)
    
    Do While Not rekordseti.EOF
        lstRezultati.AddItem rekordseti.Fields("Emri") & _
            " ---> " & rekordseti.Fields("Mbiemri") & " ---> " & rekordseti.Fields("ID")

        fut_vlera_tabele rekordsetiX, rekordseti.Fields("ID"), _
            rekordseti.Fields("Emri"), rekordseti.Fields("Mbiemri")

        rekordseti.MoveNext
    Loop
    
    rekordseti.Close
    databaza.Close
    Set rekordseti = Nothing
    Set databaza = Nothing
    
    Dim stDocName As String
    
    stDocName = "berEmployee"
    DoCmd.OpenReport stDocName, acPreview, , , acWindowNormal
    
End Sub

Public Sub mbyll_raportet()

    Do While Reports.Count > 0
        DoCmd.Close acReport, Reports(0).Name
    Loop

End Sub

Public Sub fut_vlera_tabele(rekordsetiX, strId As String, _
    strEmri As String, strMbiemri As String)

    With rekordsetiX
        .AddNew
            !ID = strId
            !Emri = strEmri
            !Mbiemri = strMbiemri
        .Update
        .Bookmark = .LastModified
    End With

End Sub

Public Sub krijo_tabelen(ByRef databaza, tblName)

    Set tabela = databaza.CreateTableDef(tblName)
    
    With tabela
        Set Feld1 = .CreateField("ID", dbText, 12)
        Set Feld2 = .CreateField("Emri", dbText, 25)
        Set Feld3 = .CreateField("Mbiemri", dbText, 25)
            .Fields.Append Feld1
            .Fields.Append Feld2
            .Fields.Append Feld3
    End With
    
    databaza.TableDefs.Append tabela

End Sub

Public Sub fshij_tabelen(ByRef databaza, tblName)

    Dim i
    For i = 0 To databaza.TableDefs.Count - 1
        If databaza.TableDefs(i).Name = tblName Then
            databaza.TableDefs.Delete tblName
            Exit Sub
        End If
    Next i
    
End Sub 

Lidhja per bazen e Accessit (2007):
bazen e Accessit (2007)

[little-boy]

hot_prinz, ke mundesi qe bazen ta Konvertojsh ne access 2003?

[hot_prinz]

jo per momentin se ketu ne pune nuk kam Access 2007, por e perpunova databazen tende te versionit 2003.

[little-boy]

Te Lumt Hot_prinz,

Kjo eshte ajo qfar kam deshiruar. Bravoo!

Faliminderit